DI - Method Monitoringダッシュボードではどのような規則が使用されていますか？ - WKB326642
環境
- wcc - Data Intelligence
回答
Data Intelligenceは、Watersのラッパーに組み込まれた分析パッケージを備えています。
Method Monitoringダッシュボードでは、以下の操作を実行できます。
· 特定のピーク名を含むすべての取り込みポイントのトレンドを表示する。
· ピークのトレンドを事前定義された管理図規則と比較し、規則違反を明確に強調表示する。
· 日付範囲、プロジェクト、システム、およびサンプルタイプによってデータを絞り込む。
· 保持時間、ピーク面積、ピーク高さなどのフィールドのデータを表示する。
以下の点に注意してください。
- 各ダッシュボードシートで適用および参照される規則には、Western ElectricおよびNelsonの規則セットが採用されています。
- 日付範囲、プロジェクト、システム、およびサンプルタイプのフィルターを適用すると、平均値およびシグマの基準線の計算に影響します。データセット全体に基づいて平均値およびシグマの基準線を計算する場合は、ピーク名のみを設定し、X軸の青いズームバーを使用して、データのより小さなサブセットを表示してください。
- ダッシュボードをカスタム分析として保存すると、すべての規則計算を変更できます。
次の表に、ダッシュボードで使用可能な各種規則と、規則セット間の比較を示します。
規則カテゴリ |
管理図の例 |
Western Electric規則の説明 |
Nelson規則の説明 |
検出された問題 |
3σを超えるポイント |
|
1つのポイントが中心線から3標準偏差を超えて離れている。（規則1） |
1つのポイントが中心線から3標準偏差を超えて離れている。（規則1） |
サンプルが著しく管理外の状態にある。 |
2σを超えるポイント |
|
連続する3つのポイントのうち2つが、中心線から同じ側に2標準偏差を超えて離れている。（規則2） |
連続する3つのポイントのうち2つ（または3つ）が、中心線から同じ方向に2標準偏差を超えて離れている。（規則5） |
サンプルが中程度の管理外状態になる傾向が見られる。 |
1σを超えるポイント |
|
連続する5つのポイントのうち4つが、中心線から同じ側に1標準偏差を超えて離れている。（規則3） |
連続する5つのポイントのうち4つ（または5つ）が、中心線から同じ方向に1標準偏差を超えて離れている。（規則6） |
サンプルが軽度の管理外状態になる強い傾向が見られる。 |
中心線の片側に連続するポイント |
|
8つ以上の連続するポイントが中心線の同じ側にある。（規則4） |
連続する9つ以上のポイントが中心線の同じ側にある。（規則2） |
長期的な偏りが存在する。 |
トレンド |
|
N/A |
連続する6つ以上のポイントが継続的に増加（または減少）している。（規則3） |
トレンドが存在する。 |
振動 |
|
N/A |
連続する14個以上の点の変化方向が交互に変わり、上昇と下降を繰り返している。（ルール4） |
これほどの変動は、ノイズでは説明できない。 |
ばらつきの減少 |
|
N/A |
連続する15個の点がすべて、中心線の両側の1標準偏差以内にある。（ルール7） |
1標準偏差以内に収まる点ばかりではなく、通常はさらに大きなばらつきが予想される。 |
ばらつきの増加 |
|
N/A |
連続する8個の点があり、そのいずれも平均値から1標準偏差以内にはなく、かつ中心線の両側に分布している。（ルール8） |
中心線から1標準偏差以内の帯域に点がないまま、中心線の上下を行き来する現象が偶然に起こることはまれである。 |
組み込み分析パッケージでは、データセットまたは分析内に計算フィールドを作成できます。
ルールを実装するため、分析レベルで計算フィールドが作成されています。
以下の表に、分析に含まれるすべての計算フィールドを示します。
- グラフの参照線：以下の表に、各ダッシュボードシートのグラフプロパティで参照線として使用される計算フィールドを示します。
計算フィールド名 |
数式 |
平均値 |
avgOver(AnalysisField, [ ], PRE_AGG) |
-1σ |
(avgOver(AnalysisField, [ ], PRE_AGG))-(stdevOver(AnalysisField, [ ], PRE_AGG)) |
-2σ |
(avgOver(AnalysisField, [ ], PRE_AGG))-(2*(stdevOver(AnalysisField, [ ], PRE_AGG))) |
-3σ |
(avgOver(AnalysisField, [ ], PRE_AGG)) - (3*(stdevOver(AnalysisField, [ ], PRE_AGG))) |
+1σ |
(avgOver(AnalysisField, [ ], PRE_AGG))+(stdevOver(AnalysisField, [ ], PRE_AGG)) |
+2σ |
(avgOver(AnalysisField, [ ], PRE_AGG))+(2*(stdevOver(AnalysisField, [ ], PRE_AGG))) |
+3σ |
(avgOver(AnalysisField, [ ], PRE_AGG))+(3*(stdevOver(AnalysisField, [ ], PRE_AGG))) |
2. 分析対象のフィールドを変更できるようにするには、「AnalysisField」パラメータ用の計算フィールドが必要です。同じ書式で分析用の新しいフィールドを追加することで、この計算フィールドを拡張できます。 また、このフィールドはY軸の値フィールドとして追加されます。
計算フィールド名 |
数式 |
AnalysisField |
ifelse( ${AnalysisField}='Amount',amount, ${AnalysisField}='Area',area, ${AnalysisField}='Height', height, ${AnalysisField}='Retention Time',retentiontime, ${AnalysisField}='USP Resolution',uspresolution, ${AnalysisField}='USP Tailing', usptailing, ${AnalysisField}='Width',width, area) |
3. ルール1（「3σを超える点」シート）
「Rule1」計算フィールドは、ルールに違反するデータポイントを赤色で強調表示するため、Y軸にフィールドとして追加されます。
計算フィールド名 |
数式 |
Rule1 |
ifelse(avg(AnalysisField) > avg({ +3σ}) OR avg(AnalysisField) <avg({ -3σ}), avg(AnalysisField), NULL) |
4. ルール2（2σを超えるポイント）シート
「Rule2」計算フィールドは、ルールに違反するデータポイントを赤色で強調表示するため、Y軸にフィールドとして追加されます。
「Rule2Flag」計算フィールドをY軸にフィールドとして追加し、±2σの範囲を外れるデータポイントを琥珀色で強調表示します。
計算フィールド名 |
数式 |
R2tag |
ifelse(avg(AnalysisField) > avg({ +2σ}) OR avg(AnalysisField) < avg({ -2σ}), 1, 0) |
R2Prev1 |
lag({ R2tag}, [dateacquired ASC], 1) |
R2Prev2 |
lag({ R2tag}, [dateacquired ASC], 2) |
Rule2 |
ifelse({ R2tag} + { R2Prev1} + { R2Prev2} >= 2, avg(AnalysisField), NULL) |
Rule2Flag |
ifelse(avg(AnalysisField) > avg({ +2σ}) OR avg(AnalysisField) < avg({ -2σ}), avg(AnalysisField), NULL) |
5. ルール3（1σを超えるポイント）シート
「Rule3」計算フィールドは、ルールに違反するデータポイントを赤色で強調表示するため、Y軸にフィールドとして追加されます。
「Rule3Flag」計算フィールドをY軸にフィールドとして追加し、±1σの範囲を外れるデータポイントを琥珀色で強調表示します。
計算フィールド名 |
数式 |
R3tag |
ifelse(avg(AnalysisField) > avg({ +1σ}) OR avg(AnalysisField) < avg(-{ -1σ}), 1, 0) |
R3Prev1 |
lag({ R3tag}, [dateacquired ASC], 1) |
R3Prev2 |
lag({ R3tag}, [dateacquired ASC], 2) |
R3Prev3 |
lag({ R3tag}, [dateacquired ASC], 3) |
R3Prev4 |
lag({ R3tag}, [dateacquired ASC], 4) |
Rule3 |
ifelse({ R3tag} + { R3Prev1} + { R3Prev2} + { R3Prev3} +{ R3Prev4} >= 4,avg(AnalysisField), NULL) |
Rule 3Flag |
ifelse(avg(AnalysisField) > avg({ +1σ}) OR avg(AnalysisField) < avg(-{ -1σ}), avg(AnalysisField), NULL) |
6. ルール4（平均値の片側に連続するポイント）シート
「Rule4」計算フィールドをY軸にフィールドとして追加し、ルールに違反するデータポイントを赤色で強調表示します。
「Rule4Flag」計算フィールドをY軸にフィールドとして追加し、直前のポイントと同じく平均値の片側にあるデータポイントを琥珀色で強調表示します。
計算フィールド名 |
数式 |
R4tag |
ifelse(AnalysisField > avgOver(AnalysisField, [], PRE_AGG), 1, -1) |
Rule4 |
ifelse(avg({ R4tag}) <> 0 AND lag(avg({ R4tag}), [dateacquired ASC], 1) = avg({ R4tag}) AND lag(avg({ R4tag}), [dateacquired ASC], 2) = avg({ R4tag}) AND lag(avg({ R4tag}), [dateacquired ASC], 3) = avg({ R4tag}) AND lag(avg({ R4tag}), [dateacquired ASC], 4) = avg({ R4tag}) AND lag(avg({ R4tag}), [dateacquired ASC], 5) = avg({ R4tag}) AND lag(avg({ R4tag}), [dateacquired ASC], 6) = avg({ R4tag}) AND lag(avg({ R4tag}), [dateacquired ASC], 7) = avg({ R4tag}) , avg(AnalysisField), NULL) |
Rule4Flag |
ifelse((AnalysisField > avgOver(AnalysisField, [], PRE_AGG) OR AnalysisField < avgOver(AnalysisField, [], PRE_AGG)), AnalysisField, NULL) |
7. ルール5（傾向シート）
「Rule5」計算フィールドは、ルールに違反するデータポイントを赤色で強調表示するため、Y軸にフィールドとして追加されます。
「Rule5Flag」計算フィールドをY軸のフィールドとして追加し、直前のデータポイントから上昇または下降したデータポイントをアンバー色で強調表示します。
計算フィールド名 |
式 |
方向 |
ifelse(avg(AnalysisField) > lag(avg(AnalysisField), [dateacquired ASC], 1), 1, ifelse(avg(AnalysisField) < lag(avg(AnalysisField), [dateacquired ASC], 1), -1, 0)) |
Rule5 |
ifelse({ Direction} <> 0 AND { Direction} = lag({ Direction}, [dateacquired ASC], 1) AND { Direction} = lag({ Direction}, [dateacquired ASC], 2) AND { Direction} = lag({ Direction}, [dateacquired ASC], 3) AND { Direction} = lag({ Direction}, [dateacquired ASC], 4) AND { Direction} = lag({ Direction}, [dateacquired ASC], 5), avg(AnalysisField), NULL) |
Rule5Flag |
ifelse((avg(AnalysisField) > lag(avg(AnalysisField), [dateacquired ASC], 1) OR avg(AnalysisField) < lag(avg(AnalysisField), [dateacquired ASC], 1)), avg(AnalysisField), NULL) |
8. ルール6（振動シート）
「Rule6」計算フィールドをY軸のフィールドとして追加し、ルールに違反するデータポイントを赤色で強調表示します。
「Rule6Flag」計算フィールドをY軸のフィールドとして追加し、直前のデータポイントと比べて方向が変化したデータポイントをアンバー色で強調表示します。
計算フィールド名 |
式 |
交互変動 |
ifelse({ Direction} * lag({ Direction},[dateacquired ASC], 1) = -1, 1, 0) |
Rule6 |
ifelse({ Alternating} =1 AND lag({ Alternating}, [dateacquired ASC], 1) =1 AND lag({ Alternating}, [dateacquired ASC], 2) =1 AND lag({ Alternating}, [dateacquired ASC], 3) =1 AND lag({ Alternating}, [dateacquired ASC], 4) =1 AND lag({ Alternating}, [dateacquired ASC], 5) =1 AND lag({ Alternating}, [dateacquired ASC], 6) =1 AND lag({ Alternating}, [dateacquired ASC], 7) =1 AND lag({ Alternating}, [dateacquired ASC], 8) =1 AND lag({ Alternating}, [dateacquired ASC], 9) =1 AND lag({ Alternating}, [dateacquired ASC], 10) =1 AND lag({ Alternating}, [dateacquired ASC], 11) =1 AND lag({ Alternating}, [dateacquired ASC], 12) =1 AND lag({ Alternating}, [dateacquired ASC], 13) =1 AND lag({ Alternating}, [dateacquired ASC], 14) =1, avg(AnalysisField), NULL) |
Rule6Flag |
ifelse({ Direction} * lag({ Direction},[dateacquired ASC], 1) = -1, avg(AnalysisField), NULL) |
9. ルール7（変動幅減少シート）
「Rule7」計算フィールドをY軸のフィールドとして追加し、ルールに違反するデータポイントを赤色で強調表示します。
「Rule7Flag」計算フィールドをY軸のフィールドとして追加し、±1σの範囲内にあるデータポイントをアンバー色で強調表示します。
計算フィールド名 |
数式 |
R7Prev1 |
lag({ Rule7Flag}, [dateacquired ASC], 1) |
R7Prev2 |
lag({ Rule7Flag}, [dateacquired ASC], 2) |
R7Prev3 |
lag({ Rule7Flag}, [dateacquired ASC], 3) |
R7Prev4 |
lag({ Rule7Flag}, [dateacquired ASC], 4) |
R7Prev5 |
lag({ Rule7Flag}, [dateacquired ASC], 5) |
R7Prev6 |
lag({ Rule7Flag}, [dateacquired ASC], 6) |
R7Prev7 |
lag({ Rule7Flag}, [dateacquired ASC], 7) |
R7Prev8 |
lag({ Rule7Flag}, [dateacquired ASC], 8) |
R7Prev9 |
lag({ Rule7Flag}, [dateacquired ASC], 9) |
R7Prev10 |
lag({ Rule7Flag}, [dateacquired ASC], 10) |
R7Prev11 |
lag({ Rule7Flag}, [dateacquired ASC], 11) |
R7Prev12 |
lag({ Rule7Flag}, [dateacquired ASC], 12) |
R7Prev13 |
lag({ Rule7Flag}, [dateacquired ASC], 13) |
R7Prev14 |
lag({ Rule7Flag}, [dateacquired ASC], 14) |
Rule7 |
ifelse({ Rule7Flag} + { R7Prev1} + { R7Prev2} + { R7Prev3} + { R7Prev4} + { R7Prev5} + { R7Prev6} + { R7Prev7} + { R7Prev8} + { R7Prev9} + { R7Prev10} + { R7Prev11} + { R7Prev12} + { R7Prev13} + { R7Prev14} >= 14, avg(AnalysisField), NULL) |
Rule7Flag |
ifelse(avg(AnalysisField) < avg({ +1σ}) AND avg(AnalysisField) > avg({ -1σ}), avg(AnalysisField), NULL) |
10. ルール8（ばらつきの増大シート）
「Rule8」計算フィールドをY軸にフィールドとして追加し、ルールに違反するデータポイントを赤色で強調表示します。
「Rule8Flag」計算フィールドをY軸のフィールドとして追加し、±1σの範囲外にあるデータポイントを琥珀色で強調表示します。
計算フィールド名 |
数式 |
R8Prev1 |
lag({ Rule8Flag}, [dateacquired ASC], 1) |
R8Prev2 |
lag({ Rule8Flag}, [dateacquired ASC], 2) |
R8Prev3 |
lag({ Rule8Flag}, [dateacquired ASC], 3) |
R8Prev4 |
lag({ Rule8Flag}, [dateacquired ASC], 4) |
R8Prev5 |
lag({ Rule8Flag}, [dateacquired ASC], 5) |
R8Prev6 |
lag({ Rule8Flag}, [dateacquired ASC], 6) |
R8Prev7 |
lag({ Rule8Flag}, [dateacquired ASC], 7) |
Rule8 |
ifelse({ Rule8Flag} + { R8Prev1} + { R8Prev2} + { R8Prev3} + { R8Prev4} +{ R8Prev5} + { R8Prev6} + { R8Prev7} >= 7, avg(AnalysisField), NULL) |
Rule8Flag |
ifelse(avg(AnalysisField) > avg({ +1σ}) OR avg(AnalysisField) < avg({ -1σ}), avg(AnalysisField), NULL) |
追加情報
id326642, consecutive, noise, Xアクシス, Y-Axis, Yアクシス, インポート, リテンションタイム